***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 25, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.SUBCKT  PJS6416  D  G  S
rg     G    1t    1
m1      2    1    3    3    dmos    L=1u   W=1u
.model dmos nmos ( 
+  vto = 0.77
+   kp = 16.805
+  rds = 5e12
+theta = 1e-3
+ tnom = 25
+level = 3)   
cgs	1t	3	4.734e-10	ic = 0
rd	4	D	2.5e-3	tc = -1e-3
dds	3	2	dds
.model dds d (
+  is = 1.002e-9
+   n = 1.252
+  rs = 0.016
+  eg = 0.885
+  bv = 22  
+ ibv = 0.25e-6  
+tbv1 = 1.013e-3  
+   m = 0.2888 
+ cjo = 5.123e-11
+  vj = 0.1473)
e1	1 3 table { v(1t, S) } 
+ ((0, 0)
+  ( 1.00, 1)
+  ( 1.25, 1.25)
+  ( 1.50, 1.5 )
+  ( 1.75, 1.75)
+  ( 2.00, 2.00)
+  ( 2.50, 2.5 )
+  ( 3.00, 2.85)
+  ( 3.50, 3.15)
+  ( 4.50, 3.6 )
+  ( 5.00, 3.65)
+  ( 8.00, 3.8)
+  (10.00, 3.9)
+  (12.00, 4.00)) 
ra      4    2    2.5e-3	tc = -1e-3
ls      3    S   0.0001n
m2      1t    8    6    6   inter
e2      8    6    2    1t   2
.model	inter	nmos(vto=0	kp=10	level=1) 
cgdmax  7    2    2.935e-10 ic=0
rcgd    7    2    10meg
dgd     6    2    dgd
rdgd    2    6    10meg
.model     dgd    d(m=0.3   cjo=68p   vj=0.4)
m3      7    9    1t    1t   inter
e3      9    1t    2    1   -2
.ends
*$
